TPUG - Toronto PET Users Group/TPUG Users Group CD/TPUG Users Group CD.iso/C64/A-Monthly Disks/(c)aap.d64/condir 1000

Commodore BASIC | 2007-02-04 | 1KB | 39 lines

2 REM *** CONDIR 1000 ***
10 PRINT"[147]":POKE53281,0
15 PRINT"[159]THIS PROGRAM IS FOR THE MPS1000 PRINTER"
17 PRINT"[197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197]":PRINT
20 PRINT"[158]MAKE SURE THAT PRINTER IS ON IN IBM MODE[146]"
30 PRINT"[154]   PROGRAM WILL PRINT A DOUBLE COLUMN"
35 PRINT"  DIRECTORY IN CONDENSED PRINT TO TAPE"
37 PRINT"           TO THE DISK SLEEVE."
40 PRINT"INSERT THE DISK FOR WHICH THE DIRECTORY"
45 PRINT"       IS NEEDED INTO THE DRIVE"
50 PRINT"            HIT ANY KEY"
55 GETA$:IFA$=""THEN55
60 DIMD$(144)
70 OPEN15,8,15:OPEN4,4:PRINT#4,CHR$(15);:REM CONDENSED MODE ON
80 PRINT#4,CHR$(27)"1":REM 7/72 IN. SPACING
90 PRINT#15,"I0":PRINTCHR$(147)
100 C=0:OPEN2,8,0,"$0:*":GET#2,A$,A$
110 GET#2,A$,A$,A$,B$:A=ASC(A$+CHR$(0))+256*ASC(B$+CHR$(0)):IFST THEN190
120 E$="":IFCTHENE$=MID$(STR$(A)+"   ",2,3)
130 GET#2,A$:IFA$<>CHR$(34)ANDA$<>"B"THEN130
140 GOTO170
150 GET#2,A$:IFA$=""THEN180
160 IF(ASC(A$)AND127)<32THEN150
170 E$=E$+A$:GOTO150
180 E$=LEFT$(E$,25):D$(C)=E$:PRINTE$:C=C+1:GOTO110
190 PRINT#4,CHR$(27);"E";
200 PRINT#4,""D$(0);CHR$(27);"W";CHR$(0);CHR$(27);"F";:REM ENL. OFF EMPH. OFF
210 PRINT#4,CHR$(27)CHR$(83)CHR$(1):REM SUBSCRIPT ON
220 N=(C-1)/2:FORI=1TON-1:PRINT#4,D$(I)"  "D$(I+N):NEXT
230 IFI=NTHENPRINT#4,D$(I):GOTO250
240 PRINT#4,D$(I)"  "D$(I+N)
250 REM PRINT#4,CHR$(27);"CR":PRINT#4,E$
252 PRINT#4,E$
255 PRINT#4,CHR$(27)"@":CLOSE4:CLOSE2:CLOSE15
260 PRINTCHR$(147)"WANT TO PRINT ANOTHER DIRECTORY? (Y/N)?"
270 GETQ$:IFQ$=""THEN270
280 IFQ$="Y"THEN RUN
290 END